Our circuit is relatively simple.
https://crcit.net/c/0a3500cf57c84414afd53d279ac5571b
There's an LDR connected to the "lower half" of a voltage divider, the middle of which is connected to an "analogue" input pin (ADC) on the Arduino Pro Mini.
With no light on the LDR, the resistance of the LDR will be pretty low, and the input value on pin A0 will be low. As more light hits the LDR, the resistance increases (ensuring more of the supply voltage gets to the input pin) and the "analogue" value read by A0 increases.
When the LDR receives enough light that the input value exceeds some threshold value, we will activate the buzzer (light the LED and trigger the base pin of the transistor) and also send a (one-shot) message to a serial/UART bluetooth module.
The base pin of the transistor (connected to the siren) is pulled low through a 100K resistor - this ensures that when no signal is applied from output pin D9, the siren will not sound.
To set the threshold value (sensitivity) we have a potentiometer connected to the analogue pin A1.
This allows us to change the amount of light at which the "triggered" state is entered.
The switch connected to D8 input pin is simply a "debug" pin - if set, we'll send a continuous stream of value readings out over the serial port, to help with any debug/setting up. If the debug option is not set, we won't be "spamming" the serial port with a continuous stream of data.
int led_pin = 13;
int ldr_pin = A0;
int sensitivity = A1;
int ldr_value = 0;
int debug_pin = 8;
int siren_pin = 9;
int threshold_value = 100; // this is read from the sensitity pin
int state = 0;
int prev_state = 0;
int in_debug = 0;
void setup() {
// put your setup code here, to run once:
pinMode(led_pin, OUTPUT);
pinMode(ldr_pin, INPUT);
pinMode(sensitivity, INPUT);
pinMode(debug_pin, INPUT_PULLUP);
pinMode(siren_pin, OUTPUT);
digitalWrite(siren_pin, LOW);
digitalWrite(led_pin, LOW);
Serial.begin(9600);
Serial.println("Let's go!");
}
void loop() {
if(digitalRead(debug_pin) == LOW) {
in_debug = 1;
} else {
in_debug = 0;
}
threshold_value = analogRead(sensitivity);
ldr_value = analogRead(ldr_pin);
if(in_debug == 1) {
Serial.println(ldr_value);
}
// if we've exceeded the threshold,
if(ldr_value > threshold_value) {
state = 1;
} else {
state = 0;
}
if(state == 0) {
digitalWrite(led_pin, LOW);
digitalWrite(siren_pin, LOW);
if(prev_state != 0) {
// send a reset message to the bluetooth device
Serial.println("Reset");
}
} else {
digitalWrite(led_pin, HIGH);
digitalWrite(siren_pin, HIGH);
if(prev_state == 0) {
// send a one-shot message to the bluetooth device
Serial.println("Active");
}
}
prev_state = state;
delay(100);
// if we're in debug mode, increase the delay between loops
// (makes it less responsive, but avoids spamming the receiver
// with loads of noise)
if(in_debug == 1) {
delay(400);
}
}
Now we can simply connect a HM-10 bluetooth module to the serial pins, and have our device "talk" to a connected smart device, like a phone or tablet
